В жизни, как в такси: счетчик отмечает пройденное
даже тогда, когда мы стоим на месте.

Урок 24.
"Периодические реквизиты справочников".

   Напомню Вам, что в прошлом выпуске речь шла о периодических константах. Как оказалось - одним из интереснейших моментов была фраза "Примечание: на самом деле тут я не прав: есть в 1С, один баг, когда возникает 2  значения на 1 дату."  Пришло много заявок с просьбой рассказать об этом. Обещаю Вам, что в ближайшем выпуске, я это сделаю. Но сегодня речь пойдет о периодических реквизитах справочников. 

    Необходимость периодических реквизитов никто не отрицает. Классическим примером может служить справочник "Валюты", где существует два периодических реквизита - "Курс" и "Кратность". Но рекордсменами, на мой взгляд, все -таки является справочники "Основные средства" и "Сотрудники". 

    Включение опции «Периодический» у реквизита справочника, позволяет указать для реквизита справочника хранение истории изменений его значения. Такой реквизит в системе 1С:Предприятие называется периодическим. Этот реквизит  обладает следующим свойством: в отличие от «обычных» (не периодических) реквизитов, система 1С:Предприятие хранит значения такого реквизита по датам их изменения. При обращении к значению такого реквизита на некоторую дату выдается его значение на эту дату, либо, если таковое отсутствует, — на ближайшую предыдущую дату, на которую устанавливалось значение реквизита. 

    Важно помнить, что разные периодические реквизиты одного и того же элемента справочника не связаны между собой. Это означает, что изменять их значения можно не зависимо друг от друга. Если Вы изменяете "курс" в справочнике "Валюты", то Вас никто не заставляет изменять значение реквизита "кратность". 

    Периодическим может быть реквизит любого типа кроме текстового неограниченной длины. Периодически реквизиты имеют ограничение: для них не может быть установлен отбор и сортировка. 

Изменение значения периодических реквизитов. В отличии от констант, периодические реквизиты справочников могут быть изменены тремя способами: вручную, программно и документом. 

Ручное изменение.
При просмотре списка справочника (или элемента справочника) Вы всегда видите значение периодических реквизитов на рабочую дату.  По этому для ручного изменения значения реквизитов лучше пользоваться клавишей F5 (или меню "Действия" ->"История значения"). При этом Вам потребуется выбрать реквизит, который Вы хотите изменить. После этого открывается окно истории в котором две колонки: "Дата" и "Значение".  Здесь Вы сможете изменить любое значение и любую дату, добавить строки или удалить строки. Этот способ является встроенным в систему и не зависит от компоненты и конфигурации.
В некоторых конфигурациях существует программно реализованная возможность работы с периодическими реквизитами. Чаще всего эта возможность "прячется" под кнопкой "История".  При нажатии на эту кнопку открывается окно, в котором Вы получаете много дополнительных возможностей. Но большая часть из них сводится к удалению значений/дат и чистку истории. По крайней мере, в 4.26 конфигурации бухгалтерии я не смог изменить значения реквизита через кнопку "История".

Программное изменение.
Как и при изменении значений периодических констант, при работе с периодическими значениями справочников требуется всегда указывать дату на которую Вы хотите получить или установить значение.  Используются следующие методы.

Получить(ДатаЗн) - этот метод позволяет получить значение на указанную дату. Наиболее просто объяснит его работу на небольшом примере:
Процедура Сформировать()
    спр=СоздатьОбъект("Справочник.Валюты");
    спр.ВыбратьЭлементы(); //перебираем элементы
    Пока спр.ПолучитьЭлемент()=1 цикл
        курсВалюты=спр.курс.Получить('01.01.2002'); //получаем значение курса на 1 января 2002 года
        КратностьВалюты=спр.кратность.Получить('01.01.2002'); //получаем  кратность на 1 янв. 2002 г.
        Сообщить(спр.Наименование);
        Сообщить(курсВалюты);
        Сообщить(КратностьВалюты);
    конецЦикла;
конецПроцедуры

Комментарий к примеру: "Курс" и "Кратность" - это реквизиты справочника "Валюты". Процедура перебирает элементы справочника и сообщает наименование валюты, курс и кратность на 1 января 2002 года. Обращаю Ваше внимание на использование метода Получить: метод применяется к реквизиту.

Установить(датаУстановки, .Значение) - метод позволяет устанавливать значение периодического реквизита на любую дату.  Предыдущий пример легко изменить, чтобы процедура устанавливала значение курса и кратности для всех валют в какое-то одно значение: 
Процедура Сформировать()
    спр=СоздатьОбъект("Справочник.Валюты");
    спр.ВыбратьЭлементы(); //перебираем элементы
    Пока спр.ПолучитьЭлемент()=1 цикл
        // устанавливаем значение курса на 1 января 2002 года равным единице
        спр.курс.Установить('01.01.2002', 1); 
        //устанавливаем  кратность на 1 янв. 2002 г. равной 2.
        спр.кратность.Установить('01.01.2002', 2); 
      конецЦикла;
конецПроцедуры

Обратите внимание: в этом способе, при  записи истории не нужно использовать метод Записать(). Вообще, обращение к периодическим реквизитам - трудоемкая операция для 1С.  И  чем больше Вы получаете значений периодических реквизитов для одного объекта, тем дольше все это работает. В том случае, если приходится обрабатывать много реквизитов на одну дату у одного объекта, я рекомендую использовать метод  ИспользоватьДату()

ИспользоватьДату(Дата, УстСразу) - метод позволяет задать дату для работы со всеми периодическими реквизитами сразу для всего справочника, созданного с помощью СоздатьОбъект(). После его применения, обращение к периодическими реквизитам происходит так же как к обычным реквизитам.  Важно!!! После метода ИспользоватьДату() нельзя использовать методы Установить() и Получить(). 
Особого внимания заслуживает  флаг УстСразу. Если УстСразу=0, тогда метод начинает работать со следующей выборки элементов. Если устСразу=1, тогда метод начинает работать уже в текущей выборке

//*******************************************
Процедура Сформировать()
    спр=СоздатьОбъект("Справочник.Валюты");
    спр.ИспользоватьДату('01.01.2002');
    спр.ВыбратьЭлементы(); //перебираем элементы
    Пока спр.ПолучитьЭлемент()=1 цикл 
        спр.курс=121; // обращаемся к курсу как к простому реквизиту
        спр.кратность=233; 
        спр.записать(); //теперь обязательно надо записать изменения!!!
    конецЦикла;
КонецПроцедуры

Получение значений периодических реквизитов после метода ИспользоватьДату() - выполняется аналогичным образом:

Процедура Сформировать()
    спр=СоздатьОбъект("Справочник.Валюты");
    спр.ИспользоватьДату('01.01.2002', 1);
    спр.ВыбратьЭлементы(); //перебираем элементы
    Пока спр.ПолучитьЭлемент()=1 цикл
        курсВалюты=спр.курс; 
        КратностьВалюты=спр.кратность; 
        Сообщить(спр.Наименование);
        Сообщить(курсВалюты);
        Сообщить(КратностьВалюты);
    конецЦикла;
конецПроцедуры

Изменение периодических реквизитов справочника документами.
Периодические реквизиты могут быть изменены не только вручную и программно из обработки, но и при проведении документа. Я это считаю отдельным способом, так как методика работы в этом случае несколько отличается от обычной ситуации. Все дело в том, что при проведении документа, значение реквизита устанавливается в нужное значение, а при распроведении документа - восстанавливается предыдущее значение.  Восстановление происходит автоматически. Нет необходимости в использовании процедуры отмены обработки проведения.  Обращаю Ваше внимание на то, что такая манипуляция возможна только с периодическими реквизитами. Для обычных реквизитов это не работает. Для установки значений используется метод УстановитьРеквизитСправочника(). Этот метод можно применять только в модуле документа. Синтаксис метода:
 УстановитьРеквизитСправочника(Элем,Рекв,Зн,ДатаУст,ИмяТ,Длина,Точность);
где Элем - элемент справочника, для которого меняется значение периодического реквизита
Рекв - имя изменяемого реквизита (как оно задано в конфигураторе)
Зн - устанавливаемое значение
ИмяТ, Длина, Точность - используются для реквизитов неопределенного типа. В остальных случаях - их применение не обязательно.
Пример применения этого метода Вы может найти в типовой бухгалтерии (у меня 4.2) в документах: "Приказ о приеме на работу", "Приказ о кадровых изменениях", "Ввод в эксплуатацию ОС", "Перемещение ОС", "Принятие к учету НМА" и других документах.

    Наблюдение: на собственном опыте знаю, что бухгалтеры делают миллион ошибок, когда сталкиваются с периодическими реквизитами. Им очень трудно объяснить, что изменять значения надо через кнопку F5, что значение в расчетах может использоваться не то, которое они видят в справочнике, а какое-то другое, которое было "тогда". Универсального рецепта для борьбы с этим не знаю. В своей практике стараюсь заставлять бухгалтера менять периодическое значение только через документ. В этом случае резко уменьшается количество записи ошибок "не на ту" дату. Из-за периодических элементов очень страдает, на мой взгляд, программа Зарплата и кадры. 

Задание для самостоятельной работы:

1. Создайте документ, предназначенный для изменения курсов валют в справочнике Валюты.

2. В справочнике "Основные средства"  есть надпись "Значения периодических реквизитов указаны на дату...". Рядом кнопка для изменения даты. Как изменение даты влияет на отображаемые значения реквизитов.

На сегодня все. В следующем выпуске: объект "Периодический"